Core War: Clear/Imp

• Core War
• Strategy
• Clear/Imp

A clear/imp combines an imp spiral with a core-clear to create a warrior which performs well against stone/imps. The first modern clear/imp was published by Justin Kao in October 1996.

D-Clear with JMP/ADD Launch

A Dust-style clear/imp combines a d-clear with a JMP/ADD launched imp spiral. The imp launcher sends extra processes to speed up the d-clear.

        org    start

gate    dat    4000,       1700
bomb    dat    >2667,      11

        for    4
        dat    0,0
        rof

        spl    #4000,      >gate
clear   mov    bomb,       >gate
        djn.f  clear,      >gate

        for    23
        dat    0,0
        rof

        istep  equ 1143           ; (CORESIZE+1)/7

start   spl    clear-1
        mov    imp,        *launch
        spl    1                  ; 32 parallel processes
        spl    1
        spl    1
        spl    1
        spl    1
        spl    nxpoint
launch  djn.f  3600,       <4000

        for    2
        dat    0,0
        rof

nxpoint add.f  #istep,     launch
        djn.f  clear-1,    <3000

imp     mov.i  #1,         istep

Example Clear/Imps

Dust 0.7, Digitalis 2003 and Rise of the Dragon pair a d-clear with a JMP/ADD launcher.

Mandragora is a g2 clear with a vortex launch.

Disharmonious combines a stargate clear with a vortex launcher.