Mercenary is a paper with silk-imps which entered the KOTH.org 94 and 94nop hills on 13th April 2022. Mercenary survived 140 challenges on the 94nop hill, before being pushed off on 11th August 2024. Mercenary has also reach age 104 on the 94 hill before leaving the hill on 9th June 2026.
;redcode-94nop
;name Mercenary
;author John Metcalf
;strategy paper with silk-imps
;assert CORESIZE==8000
org qscan
qfac equ 2259
qdec equ 2140
qa equ (qfac*(qtab0-1-qptr)+1)
qb equ (qfac*(qtab0-qptr)+1)
qc equ (qfac*(qtab1-1-qptr)+1)
qd equ (qfac*(qtab1-qptr)+1)
qe equ (qfac*(qtab1+1-qptr)+1)
qf equ (qfac*(qtab2-qptr)+1)
qtime equ 18
qstep equ -7
qgap equ 87
qdecode mul.b *q1, qptr
q0 sne <qtab0, @qptr
q1 add.b qtab1, qptr
q2 mov qtab2, @qptr
qptr mov qtab2, *qdec
add #qstep, qptr
djn q2, #qtime
jmp warr, qc
qtab1 dat 4000, qd
dat 4000, qe
qscan sne qptr+qdec*qe, qptr+qdec*qe+qe
seq <qtab1+1, qptr+qdec*(qe-1)+qe-1
jmp qdecode, }q1
sne qptr+qdec*qb, qptr+qdec*qb+qd
seq <qtab0, qptr+qdec*(qb-1)+qd
jmp qdecode, {qdecode
sne qptr+qdec*qa, qptr+qdec*qa+qd
seq <qtab0-1, qptr+qdec*(qa-1)+qd
djn.a qdecode, {qdecode
sne qptr+qdec*qf, qptr+qdec*qf+qd
seq <qtab2, qptr+qdec*(qf-1)+qd
jmp qdecode, }qdecode
sne qptr+qdec*qc, qptr+qdec*qc+qc
seq <qtab1-1, qptr+qdec*(qc-1)+qc-1
jmp qdecode, {q1
sne qptr+qdec*qd, qptr+qdec*qd+qd
seq <qtab1, qptr+qdec*(qd-1)+qd-1
jmp qdecode, qa
qtab0 jmp warr, qb
qtab2 dat qgap, qf
for 60
dat 0, 0
rof
pstepa equ -3424
pstepb equ -3656
off equ 3340
warr spl 2, {300
spl 1, {400
spl 1, {500
pp mov {papera, {boot
boot spl *papera+4006, {700
papera spl @0+6, >pstepa
mov }papera, >papera
mov {papera, <paperb
paperb spl @0, >pstepb
mov.i #off, }3999-off
end