PROGRAM gamma;

{    (c) by Matthias Mhlich 02/94    }

USES
  pcrobot6;

CONST
  maxpanzerung = 200;
  notpanzerung = 30;
  e_reserve = 100; e_not = 50;
  v_e_not = 10;
  entf_weit = 200; entf_nah = 50;

VAR
  voll_ok, e_notstand, s_o_s, richtungsaenderung : boolean;
  opfer, opfer_entf, entfernung, winkel,
  ziel, richtung, geschw, dummy : integer;
  target_lock : longint;
  ortskarte : map_buffer;

PROCEDURE init;
  BEGIN
    dummy := configure(2,2,2,4,0,0);
    geschw := 40;
    opfer_entf := 9999;
    winkel := 0;
    richtung := 0;
    richtungsaenderung := false;
    ziel := -1;
    opfer := -1;
    target_lock := 0;
  END;

PROCEDURE status;
  BEGIN
    WHILE (maxpanzerung - damage > 0) and (battery > e_reserve)
      DO buy_armour(1);
    voll_ok := ((damage = maxpanzerung) and (battery = 1000));
    e_notstand := (battery < e_not);
    s_o_s := (damage < notpanzerung);
  END;

PROCEDURE bewegen;
  VAR
    neu_geschw : integer;
  {------------------------------------------------------------------------}
  FUNCTION test(x, y: shortint) : boolean;
    BEGIN
      test := (ortskarte[y,x]=arena_wall) or (ortskarte[y,x]=arena_damage);
    END;
  {------------------------------------------------------------------------}
  FUNCTION hindernis : boolean;
    BEGIN
      CASE richtung OF
        0        : hindernis := test(5,4);
        45       : hindernis := test(5,5);
        90       : hindernis := test(4,5);
        135      : hindernis := test(3,5);
        180      : hindernis := test(3,4);
        225      : hindernis := test(3,3);
        270      : hindernis := test(4,3);
        315      : hindernis := test(5,3);
          1.. 44 : hindernis := test(5,4) or test(5,5);
         46.. 89 : hindernis := test(5,5) or test(4,5);
         91..134 : hindernis := test(4,5) or test(3,5);
        136..179 : hindernis := test(3,5) or test(3,4);
        181..224 : hindernis := test(3,4) or test(3,3);
        226..269 : hindernis := test(3,3) or test(4,3);
        271..314 : hindernis := test(4,3) or test(5,3);
        316..359 : hindernis := test(5,3) or test(5,4);
      END;
    END;
  {------------------------------------------------------------------------}
  BEGIN
    get_local_map(@ortskarte);
    neu_geschw := geschw;
    IF ((entfernung > entf_weit) and (geschw < 35)) or (geschw < 10)
      THEN neu_geschw := geschw + 5;
    IF (entfernung < entf_nah) and (geschw > 15)
      THEN neu_geschw := geschw - 5;
    IF e_notstand THEN neu_geschw := v_e_not;
    IF hindernis THEN neu_geschw := 0;
    IF (neu_geschw <> geschw) or richtungsaenderung
      THEN BEGIN
        geschw := neu_geschw;
        richtung := winkel;
        movement(geschw, richtung);
        richtungsaenderung := false;
      END;
  END;

PROCEDURE schiessen;
  BEGIN
    dummy := shoot(winkel, entfernung);
  END;

PROCEDURE suchen;
  BEGIN
    ziel := scan(winkel, 3, entfernung);
    IF (ziel <> -1) and ((ziel = opfer) or (entfernung < opfer_entf) or
       (ticks - target_lock > 100)) THEN BEGIN
      opfer_entf := entfernung;
      target_lock := ticks;
      opfer := ziel;
    END;
  END;


BEGIN
  init;
  WHILE true DO BEGIN
    status;
    suchen;
    IF (ziel <> -1) and (ziel = opfer)
      THEN BEGIN
        schiessen;
        IF abs(richtung - winkel) > 10 THEN richtungsaenderung := true;
        bewegen;
      END
      ELSE winkel := (winkel + 37) mod 360;
  END;
END.